注：操作有风险，请自行备份好数据，本教程仅供参考。
@echo off
echo *********************************************
echo 警告:该bat会对你输入的盘符根目录进行以下操作,
echo *****删除所有.lnk及.vbs结尾的文件,
echo *****去掉所有文件及文件夹的H+S(系统和隐藏)属性,
echo *****删除所有以"文件夹".exe命名的程序文件
echo 建议:右键以管理身份运行,
echo *****手动检查失败项.
echo *********************************************
echo 更新:1.去掉所有文件及文件夹HS属性的前置条件,
echo *******由HS(系统且隐藏),改为H(隐藏)
echo *****2.对"文件夹".exe命名的程序采取删除操作
echo *********************************************
echo *
echo *********第一步，输入中病毒的U盘盘符
set /p vbspath=请输入U盘盘符（例：“F:”）：
echo *********************************************
echo *
echo *********第二步，关闭进程
taskkill /im wscript.exe /f
echo *********************************************
echo *
echo *********第三步，删除快捷方式（lnk）
%vbspath%
for /f "delims=" %%a in ('dir /a-h /b %vbspath%\*.lnk') do (
echo 删除%%a
del /a-s-h "%%a"
)
rem 弃用del /a-s-h *.lnk
echo *********************************************
echo *
echo *********第四步，删除病毒,针对2.vbs(71.3kb版本),iexplore.vbs
if exist *.vbs (
attrib -S -H *.vbs && del *.vbs && echo 删除%vbspath%\*.vbs
) else echo 无文件%vbspath%\*.vbs
%SystemDrive%
cd %USERPROFILE%\AppData\Roaming
if exist *.vbs (
attrib -S -H *.vbs && del *.vbs && echo 删除%USERPROFILE%\AppData\Roaming\*.vbs
) else echo 无文件%USERPROFILE%\AppData\Roaming\*.vbs
cd %USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup
if exist *.vbs (
attrib -S -H *.vbs && del *.vbs && echo 删除%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\*.vbs
) else echo 无文件%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\*.vbs
if exist iexplore.lnk (
attrib -S -H iexplore.lnk && del iexplore.lnk && echo 删除%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\iexplore.lnk
) else echo 无文件%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup\iexplore.lnk
cd %USERPROFILE%\AppData\Roaming\Internet Explorer
if exist *.vbs (
attrib -S -H *.vbs && del *.vbs && echo 删除%USERPROFILE%\AppData\Roaming\Internet Explorer\*.vbs
) else echo 无文件%USERPROFILE%\AppData\Roaming\Internet Explorer\*.vbs
echo *********************************************
echo *
echo *********第五步，取消文件的系统隐藏属性
%vbspath%
for /f "delims=" %%a in ('dir /ah /b %vbspath%') do (
echo %%a
attrib -s -h "%%a"
)
echo *********************************************
echo *
echo *********第六步，删除所有以"文件夹".exe命名的程序文件
for /f "delims=" %%a in ('dir /ad /b %vbspath%') do (
if exist %%a.exe (
del "%%a.exe" && echo 删除%%a.exe
) else echo 无文件%%a.exe
)
rem 弃用attrib -s -h /s /d
echo *********************************************
rem echo Copyright 2018-2021 by sf <sfspace@163.com>
pause